Start with basic formulas for trapezoidal ramps

(%i615) remvalue(all)$
'RampDist=eq0: (Acc/2)*AccTime^2;
'ConstVelDist=eq1: Vel*VelTime;
'RampDnDist=eq2: (Dec/2)*DecTime^2;
'TotalDist=eq3: eq0+eq1+eq2;
'TotalTime=eq4: AccTime+VelTime+DecTime;
'Vel=eq5: Acc*AccTime;

Result

Assume Dec=Acc and DecTime=AccTime for simplicity
There Dec must be expressed in terms of Acc because there are
only three equations so there can be only 3 unknowns

(%i622) eq6: subst([Dec=Acc,DecTime=AccTime],[eq3,eq4])$
'TotalDist=eq7:eq6[1];
'TotalTime=eq8:eq6[2];

Result

Solve in terms of TotalTime, TotalDist, Vel

(%i625) eq9: solve([Vel=eq5,TotalDist=eq7,TotalTime=eq8],[AccTime,VelTime,Acc])$
eq9[1][1];
eq9[1][2];
eq9[1][3];

Result

Allow for 1.5*Acc for S-Curve

(%i629) 'MaxAcc=eq10:(3/2)*rhs(eq9[1][3]);

Result

Assign numbers
I use IPS ( inch pounds seconds )
mass is in sliches where 1g = 386.1 in/sec^2
Frictions is an assumed number
SysPrs is the system pressure in psi.

(%i630) TotalDist: 12*25;
TotalTime: 9;
Vel: 40;
W: 200000;
g: 386.1;
m: W/g;
Friction: 10000;
SysPrs: 3000;

Result

Compute Maximum Acceleration, in/sec^2
The frequency of acceleration is 1/(2*Min(AccTime,DecTime))
The frequency of acceleration should be much lower
than the natural frequency or active damping techniques
must be used.

(%i638) 'AccTime=AccTime: rhs(eq9[1][1]),numer;
'VelTime=VelTIme: rhs(eq9[1][2]),numer;
'Acc=Acc: rhs(eq9[1][3]),numer;
'MaxAcc=MaxAcc: eq10,numer;

Result

Estimate Max Force, pounds force

(%i642) Force: m*(g+MaxAcc)+Friction,numer;

Result

Cylinder Size, in^2
AreaA is the cap side area
AreaB is the rod side area
The 2* is because there are two cylinders in parallel

(%i643) CylDia: 7.5;
RodDia: 6.5;
AreaA: 2*(%pi/4)*CylDia^2,numer;
AreaB: 2*(%pi/4)*(CylDia^2-RodDia^2),numer;

Result

Steady State Pressures, psi
PrsA is the cap side pressure
PrsB is the rod side pressure

(%i647) 'PresAStatic=PrsAStatic: (AreaB*SysPrs+W)/(AreaA+AreaB);
'PrsBStatic=PrsBStatic: (AreaA*SysPrs-W)/(AreaA+AreaB);
PrsAStatic*AreaA-PrsBStatic*AreaB;

Result

Constant Velocity Pressures Going Up, psi

(%i650) 'PrsAVel=PrsAVel: (AreaB*SysPrs+W+Friction)/(AreaA+AreaB);
'PrsBVel=PrsBVel: (AreaA*SysPrs-W-Friction)/(AreaA+AreaB);
PrsAVel*AreaA-PrsBVel*AreaB;

Result

Pressures at Peak Acceleration, psi

(%i653) 'PrsAAcc=PrsAAcc: (AreaB*SysPrs+W+Friction+m*MaxAcc)/(AreaA+AreaB);
'PrsBAcc=PrsBAcc: (AreaA*SysPrs-W-Friction-m*MaxAcc)/(AreaA+AreaB);
PrsAAcc*AreaA-PrsBAcc*AreaB;

Result

Created with wxMaxima.